1 GOSUB61000
10 REM *******************
12 REM **               **
13 REM **  LAIR OF THE  **
15 REM **               **
20 REM **  NECROMANCER  **
25 REM **               **
30 REM *******************
40 :
45 REM WRITTEN BY ROB RUDD
50 REM           JULY 1984
55 :
60 REM TRANSLATED FOR THE COMMODORE
65 REM            BY DONNA K. WOODY
70 :
80 POKE53280,1:POKE53281,0:PRINT"[158]":POKE53272,23:PRINTCHR$(8)
200 PRINT"[147]"
210 LC=1
250 GOTO11000
300 PRINT
301 INPUT"===>";C$
303 CM=0:PRINT
305 IFLEFT$(C$,3)="USE"ORLEFT$(C$,3)="[213]SE"THENCM=2
310 IFLEFT$(C$,1)="S"ORLEFT$(C$,1)="[211]"THENCM=3
315 IFLEFT$(C$,1)="N"ORLEFT$(C$,1)="[206]"THENCM=4
320 IFLEFT$(C$,1)="E"ORLEFT$(C$,1)="[197]"THENCM=5
325 IFLEFT$(C$,1)="W"ORLEFT$(C$,1)="[215]"THENCM=6
330 IFLEFT$(C$,4)="LOOK"ORLEFT$(C$,4)="[204]OOK"THENCM=7
335 IFLEFT$(C$,3)="GET"ORLEFT$(C$,3)="[199]ET"THENCM=9
337 IFLEFT$(C$,4)="QUIT"ORLEFT$(C$,4)="[209]UIT"THENGOSUB60000
340 IFCM<>2THENGOTO435
345 PRINT:INPUT"[213]SE WHAT ITEM?[160]";U$
347 UD=0:PRINT
350 IFLEFT$(U$,12)="MAGIC SWORD"THENUD=1
355 IFLEFT$(U$,4)="HORN"THENUD=2
360 IFLEFT$(U$,10)="RED POTION"THENUD=3
365 IFLEFT$(U$,13)="MAGIC POTION"THENUD=4
370 IFLEFT$(U$,7)="SCEPTRE"THENUD=5
375 IFLEFT$(U$,12)="DRAGONSLAYER"THENUD=6
380 IFLEFT$(U$,7)="COMPASS"THENUD=7
385 IFLEFT$(U$,11)="MAGIC DUST"THENUD=8
390 IFLEFT$(U$,10)="HOLY WATER"THENUD=9
395 IFLEFT$(U$,4)="GOLD"THENUD=10
400 IFUD=0THENPRINT"[215]HAT?":GOTO300
405 GOTO10500
410 IFUD=3THENRI=2
415 IFUD=4THENPS=2
420 IFUD=8THENMD=2
425 IFUD=9THENHW=2
430 IFUD=10THENGL=2
435 IFLEFT$(C$,1)="I"ORLEFT$(C$,1)="[201]"THENGOTO20000
440 IFLEFT$(C$,6)="[193]NSWER"ORLEFT$(C$,6)="ANSWER"THENCM=8
445 IFC$=""THENGOTO301
450 IFLEFT$(C$,3)="COM"ORLEFT$(C$,3)="[195]OM"THENGOTO30000
455 IFCM=0THENPRINT"[206]O COMPRENDO.":GOTO300
460 RETURN
499 :
500 REM *** LOCATION #1 ***
501 :
510 PRINT"[217]OU ARE AT THE ENTRANCE OF THE DUNGEON."
515 PRINT"[201]T IS HUMID AND MUCKY SMELLING IN HERE."
520 PRINT"[212]HERE IS A SIGN ON THE WALL THAT READS:"
525 PRINT" '[212]HOU ART NOW WITHIN THE LAIR OF THE"
527 PRINT"  EVERPOWERFUL [206]ECROMANCER.  [212]HOU SHALT"
528 PRINT"  MEET THY DOOM.'"
530 PRINT:PRINT"[212]HERE IS AN EXIT TO THE EAST."
540 GOSUB300
560 IFCM=2THENPRINT"[206]O EFFECT."
570 IFCM=3ORCM=4ORCM=6THENPRINT"[217]OU CANNOT GO THAT DIRECTION."
580 IFCM=5THENLC=2:GOTO250
590 IFCM=7THENGOTO500
610 IFCM=9THENPRINT"[206]OTHING HERE."
620 GOTO540
999 :
1000 REM *** LOCATION #2 ***
1001 :
1010 PRINT"[212]HIS ROOM HAS SEVERAL HUMAN SKELETONS"
1015 PRINT"SCATTERED ABOUT THE GROUND."
1020 IFCP=0THENPRINT"[212]HERE IS A COMPASS ON THE GROUND NEAR"
1025 IFCP=0THENPRINT"ONE OF THE SKELETONS."
1027 PRINT
1030 PRINT"[212]HERE ARE EXITS TO THE WEST, SOUTH, AND EAST."
1040 GOSUB300
1050 IFCM=2THENPRINT"[206]O EFFECT."
1060 IFCM=3THENLC=5
1070 IFCM=4THENPRINT"[217]OU CANNOT GO THAT DIRECTION."
1080 IFCM=5THENLC=3
1090 IFCM=6THENLC=1
1100 IFCM=3ORCM=5ORCM=6THENGOTO250
1110 IFCM=7THENGOTO1000
1120 IFCM=9ANDCP>0THENPRINT"[206]OTHING HERE."
1125 IFCM=9ANDCP=0THENPRINT"[195]OMPASS TAKEN.":CP=1
1130 GOTO1040
1499 :
1500 REM *** LOCATION #3 ***
1501 :
1510 PRINT"[212]HERE IS AN ALTAR IN THIS ROOM."
1520 IFHW=0THENPRINT"[193]TOP OF THE ALTAR IS A VIAL OF HOLY     WATER."
1525 PRINT
1530 PRINT"[212]HERE ARE EXITS TO THE SOUTH AND WEST."
1540 GOSUB300
1550 IFCM=2THENPRINT"[206]O EFFECT."
1560 IFCM=3THENLC=4:GOTO250
1570 IFCM=4ORCM=5THENPRINT"[217]OU CANNOT GO THAT DIRECTION."
1580 IFCM=6THENLC=2:GOTO250
1590 IFCM=7THENGOTO1500
1600 IFCM=9ANDHW>0THENPRINT"[206]OTHING HERE."
1605 IFCM=9ANDHW=0THENPRINT"[200]OLY WATER TAKEN.":HW=1
1610 GOTO1540
1999 :
2000 REM *** LOCATION #4 ***
2001 :
2010 PRINT"[212]HERE IS A STATUE OF A KOBOLD IN HERE."
2020 IFSC=0ANDD4=0THENPRINT"[201]T IS HOLDING A SCEPTRE."
2025 IFSC=0ANDD4=1THENPRINT"[212]HERE IS A SCEPTRE ON THE GROUND NEAR   THESTATUE."
2030 PRINT"[193] SIGN AT THE BASE OF THE STATUE READS:  '[198]ORK OVER THE DINERO'."
2035 PRINT
2040 PRINT"[212]HERE ARE EXITS TO THE SOUTH AND WEST."
2045 GOSUB300
2050 IFCM=2ANDUD=10THENPRINT"[212]HE STATUE LET GO OF THE SCEPTRE.":D4=1
2060 IFCM=2ANDUD<>10THENPRINT"[206]O EFFECT."
2070 IFCM=9ANDD4=0THENPRINT"[217]OU CANNOT PRY THE SCEPTRE AWAY FROM THESTATUE'S GRASP."
2080 IFCM=9ANDD4=1ANDSC>0THENPRINT"[206]OTHING HERE."
2090 IFCM=9ANDD4=1ANDSC=0THENPRINT"[211]CEPTRE TAKEN.":SC=1
2100 IFCM=3THENLC=7:GOTO250
2110 IFCM=4ORCM=5THENPRINT"[217]OU CANNOT GO THAT DIRECTION."
2120 IFCM=6THENLC=3:GOTO250
2130 IFCM=7THENGOTO2000
2140 GOTO2045
2499 :
2500 REM *** LOCATION #5 ***
2505 IFD5=1ANDMD=0THENPRINT"[212]HERE IS A POUCH OF MAGIC DUST ON THE   GROUND IN HERE."
2510 IFD5=0THENPRINT"[212]HERE IS A GROUP OF UNDEAD SKELETONS IN THIS ROOM."
2512 IFD5=0THENPRINT"[212]HEY ARE ATTACKING."
2515 IFD5=1ANDMD>0THENPRINT"[212]HIS ROOM IS EMPTY."
2516 PRINT
2517 IFD5=1THENPRINT"[212]HERE ARE EXITS TO THE EAST AND SOUTH."
2520 GOSUB300
2525 IFD5=1THENGOTO2550
2530 IFCM=2ANDUD=9THENPRINT"[212]HE HOLY WATER DESTROYED THE SKELETONS.":D5=1:GOTO2500
2540 PRINT"[212]OO LATE, THE SKELETONS BEGIN TO RIP"
2542 PRINT"ALL OF YOUR FLESH OFF AND HAVE A GREAT  FEAST.":GOTO50000
2550 IFCM=2THENPRINT"[206]O EFFECT."
2560 IFCM=3THENLC=17:GOTO250
2570 IFCM=4ORCM=6THENPRINT"[217]OU CANNOT GO THAT DIRECTION."
2580 IFCM=5THENLC=2:GOTO250
2590 IFCM=7THENGOTO2500
2600 IFCM=9ANDMD>0THENPRINT"[206]OTHING HERE."
2610 IFCM=9ANDMD=0THENPRINT"[205]AGIC DUST TAKEN.":MD=1
2620 GOTO2520
2999 :
3000 REM *** LOCATION #7 ***
3001 :
3010 PRINT"[212]HERE IS A GLASS CASE IN THE MIDDLE OF  THIS ROOM."
3020 IFDS=0THENPRINT"[212]HERE IS A DRAGONSLAYER IN THE THE CASE."
3030 PRINT:PRINT"[212]HERE ARE EXITS TO THE NORTH AND WEST."
3040 GOSUB300
3050 IFCM=2ANDUD=8THENPRINT"[212]HE MAGIC DUST EVAPORATED PART OF THE   GLASS CASE.":D7=1
3060 IFCM=2ANDUD<>8THENPRINT"[206]O EFFECT."
3070 IFCM=3ORCM=5THENPRINT"[217]OU CANNOT GO THAT DIRECTION."
3080 IFCM=4THENLC=4:GOTO250
3090 IFCM=6THENLC=17:GOTO250
3100 IFCM=7THENGOTO3000
3105 IFCM=9ANDD7=1ANDDS=1THENPRINT"[206]OTHING HERE."
3110 IFCM=9ANDD7=1ANDDS=0THENPRINT"[196]RAGONSLAYER TAKEN.":DS=1
3120 IFCM=9ANDD7=0THENPRINT"[217]OU CANNOT BREAK THE GLASS CASE.  [201]T IS OBVIOUSLY MAGIC."
3130 GOTO3040
3499 :
3500 REM *** LOCATION #8 ***
3501 :
3510 IFD8=1ANDRI>0THENPRINT"[193] DEAD DRAGON IS ON THE FLOOR IN HERE."
3512 IFD8=1ANDRI>0THENPRINT"[212]HEN ROOM IS OTHERWISE EMPTY."
3520 IFD8=1ANDRI=0THENPRINT"[212]HE DEAD DRAGON HAS A RED POTION STRUNG AROUND IT'S NECK."
3530 IFD8=0THENPRINT"[212]HERE IS A FEROCIOUS LOOKING DRAKE IN"
3532 IFD8=0THENPRINT"HERE THAT IS ABOUT TO ATTACK."
3535 IFD8=1THENPRINT:PRINT"[212]HERE IS AN EXIT TO THE EAST."
3540 GOSUB300
3550 IFD8=1THENGOTO3590
3560 IFCM=2ANDUD=6THENPRINT"[202]UST AS THE DRAKE WAS ABOUT TO UNLEASH"
3561 IFCM=2ANDUD=6THENPRINT"IT'S FIERY WEAPON, YOU SLASH IT IN THE"
3562 IFCM=2ANDUD=6THENPRINT"NECK AND IT FALLS TO THE GROUND, DEAD."
3565 IFCM=2ANDUD=6THEND8=1:GOTO3500
3570 PRINT"[212]OO LATE. [212]HE DRAKE SPITS OUT BOILING"
3572 PRINT"LAVA, WHICH INSTANTLY FRIES YOU. [201]T'S   ALL OVER.":GOTO50000
3590 IFCM=2THENPRINT"[206]O EFFECT."
3600 IFCM=3ORCM=4ORCM=6THENPRINT"[217]OU CANNOT GO THAT DIRECTION."
3610 IFCM=5THENLC=16:GOTO250
3620 IFCM=7THENGOTO3500
3630 IFCM=9ANDRI>0THENPRINT"[206]OTHING HERE."
3640 IFCM=9ANDRI=0THENPRINT"[208]OTION TAKEN.":RI=1
3650 GOTO3540
3999 :
4000 REM *** LOCATION #9 ***
4001 :
4010 IFMS=0THENPRINT"[212]HERE  IS A RATHER LARGE STONE IN THIS"
4011 IFMS=0THENPRINT"ROOM WITH A SWORD DRIVEN DIRECTLY INTO"
4012 IFMS=0THENPRINT"THE STONE. [193]S YOU APPROACH THE SWORD IT BEGINS TO GLOW."
4020 IFMS>0THENPRINT"[212]HERE IS NOTHING IN THIS ROOM BUT A     LARGE STONE."
4030 PRINT:PRINT"[212]HERE ARE EXITS TO THE SOUTH AND WEST."
4040 GOSUB300
4050 IFCM=2ANDUD=4THENPRINT"[217]OU DRINK THE MAGIC POTION AND YOU"
4051 IFCM=2ANDUD=4THENPRINT"BECOME EXTREMELY STRONG. [217]OU ARE ABLE"
4052 IFCM=2ANDUD=4THENPRINT"TO PULL THE SWORD OUT OF THE STONE."
4053 IFCM=2ANDUD=4THENPRINT"[205]AGIC SWORD TAKEN.":MS=1
4060 IFCM=2ANDUD<>4THENPRINT"[206]O EFFECT."
4070 IFCM=3THENLC=15:GOTO250
4080 IFCM=4ORCM=5THENPRINT"[217]OU CANNOT GO THAT DIRECTION."
4090 IFCM=6THENLC=16:GOTO250
4100 IFCM=7THENGOTO4000
4110 IFCM=9ANDMS=0THENPRINT"[217]OU CANNOT PULL THE SWORD OUT OF THE STONE."
4120 IFCM=9ANDMS=1THENPRINT"[206]OTHING HERE."
4130 GOTO4040
4499 :
4500 REM *** LOCATION #10 ***
4501 :
4510 PRINT"[212]HIS ROOM IS EMPTY. [201]T HAS A DOOR ON    EACH OF THE FOUR WALLS."
4520 GOSUB300
4530 IFCM=2ANDUD=7THENCC=2:PRINT"[217]OU DISCOVER THAT THE WALLS IN HERE ARE"
4531 IFCM=2ANDUD=7THENPRINT"REVOLVING. [217]OU CAN USE THE COMPASS TO"
4532 IFCM=2ANDUD=7THENPRINT"GO THE DIRECTION YOU WISH."
4540 IFCM=2ANDUD<>7THENPRINT"[206]O EFFECT."
4550 IFCC>0THENGOTO4620
4560 X=INT(RND(1)*4)
4570 IFX=0THENLC=16
4580 IFX=1THENLC=15
4590 IFX=2THENLC=18
4600 IFX=3THENLC=11
4610 IFCM=3ORCM=4ORCM=5ORCM=6THENCC=0:GOTO250
4620 IFCM=3THENLC=18
4630 IFCM=4THENLC=16
4640 IFCM=5THENLC=15
4650 IFCM=6THENLC=11
4655 IFCM>2ANDCM>7THENCC=0:GOTO250
4660 IFCM=7THENGOTO4500
4670 IFCM=9THENPRINT"[206]OTHING HERE."
4680 CC=CC-1
4690 GOTO4520
4999 :
5000 REM *** LOCATION #11 ***
5001 :
5010 IFE1=1ANDHO>0THENPRINT"[212]HIS ROOM IS EMPTY."
5020 IFE1=1ANDHO=0THENPRINT"[212]HERE IS A HORN LYING ON THE FLOOR OF   THIS ROOM."
5030 IFE1=0THENPRINT"[201]NHABITING THIS ROOM IS A DAEMON WHO IS"
5031 IFE1=0THENPRINT"VIOLENTLY ADVANCING IN YOUR DIRECTION."
5040 IFE1=1THENPRINT"[212]HERE IS AN EXIT TO THE NORTH."
5050 GOSUB300
5060 IFE1=1THENGOTO5090
5070 IFCM=2ANDUD=5THENPRINT"[212]HE SCEPTRE BANISHED THE DAEMON BACK TO"
5071 IFCM=2ANDUD=5THENPRINT"HIS OWN PLANE OF EXISTANCE.":E1=1:GOTO5000
5080 IFE1=0AND(CM<>2ORUD<>5)THENPRINT"[212]OO LATE, THE DAEMON ATTACKS AND RIPS"
5081 IFE1=0AND(CM<>2ORUD<>5)THENPRINT"YOU IN HALF.":GOTO50000
5085 GOTO5050
5090 IFCM=2THENPRINT"[206]O EFFECT."
5100 IFCM=3ORCM=5ORCM=6THENPRINT"[217]OU CANNOT GO THAT DIRECTION."
5110 IFCM=4THENLC=10:GOTO250
5120 IFCM=7THENGOTO5000
5125 IFCM=9ANDHO>0THENPRINT"[206]OTHING HERE."
5130 IFCM=9ANDHO=0THENPRINT"[200]ORN TAKEN.":HO=1
5140 GOTO5050
5999 :
6000 REM *** LOCATION #12 ***
6001 :
6010 PRINT"[212]HERE ARE TWO VERY BIG GIANTS IN HERE."
6011 PRINT"[212]HEY BOTH SEE YOU AND START YOUR WAY."
6020 GOSUB300
6025 IFCM<>2ORUD<>3THENGOTO6120
6030 PRINT"[212]HE POTION TURNED YOU INVISIBLE.  [212]HE"
6031 PRINT"GIANTS ARE BAFFLED AND DO NOTHING BUT"
6032 PRINT"STAND THERE AND SCRATCH THEIR HEADS."
6040 IFPS=0THENPRINT"[217]OU SEE A POTION ON THE GROUND."
6045 PRINT:PRINT"[212]HERE IS AN EXIT TO THE NORTH."
6050 GOSUB300
6060 IFCM=2THENPRINT"[206]O EFFECT."
6070 IFCM=3ORCM=5ORCM=6THENPRINT"[217]OU CANNOT GO THAT DIRECTION."
6080 IFCM=4THENLC=15:GOTO250
6090 IFCM=7THENPRINT"[212]HERE ARE TWO VERY BAFFLED GIANTS IN    HERE.":GOTO6040
6100 IFCM=9ANDPS>0THENPRINT"[206]OTHING HERE."
6110 IFCM=9ANDPS=0THENPRINT"[208]OTION TAKEN.":PS=1
6115 GOTO6050
6120 PRINT"[212]OO LATE. [207]NE OF THE GIANTS PICKS YOU   UP AND CRUSHES YOUR LITTLE BODY."
6121 GOTO50000
6499 :
6500 REM *** LOCATION #13 ***
6501 :
6510 PRINT"[212]HIS ROOM HAS A LARGE MOAT BLOCKING THE"
6511 PRINT"EXIT ON THE EAST SIDE.  [212]HERE IS NO WAY AROUND THE MOAT."
6520 GOSUB300
6530 IFCM=2ANDUD=2THENPRINT"[215]ITH A BLOW OF THE HORN, THE MOAT PARTS"
6531 IFCM=2ANDUD=2THENPRINT"RIGHT DOWN THE MIDDLE, ALLOWING YOU TO"
6532 IFCM=2ANDUD=2THENPRINT"GET TO THE OTHER SIDE.":AM=1
6540 IFCM=2ANDUD<>2THENPRINT"[206]O EFFECT."
6550 IFCM=3ORCM=6THENPRINT"[217]OU CANNOT GO THAT DIRECTION."
6560 IFCM=5ANDAM=0THENPRINT"[217]OU WALK INTO THE MOAT AND GET ATTACKED"
6561 IFCM=5ANDAM=0THENPRINT"BY CROCODILES. [212]HEY TEAR YOU TO PIECES.":GOTO50000
6570 IFCM=5ANDAM=1THENLC=14:GOTO250
6580 IFCM=4THENLC=18:AM=0:GOTO250
6590 IFCM=7ANDAM=1THENPRINT"[212]HERE IS A MOAT IN THIS ROOM THAT IS"
6591 IFCM=7ANDAM=1THENPRINT"PARTED DOWN THE MIDDLE ALLOWING ACCESS"
6592 IFCM=7ANDAM=1THENPRINT"TO THE EXIT ON THE EAST WALL."
6600 IFCM=7ANDAM=0THENGOTO6500
6610 IFCM=9THENPRINT"[206]OTHING HERE."
6620 GOTO6520
6999 :
7000 REM *** LOCATION #14 ***
7001 :
7010 PRINT"[217]OU ENTER A VERY LARGE ROOM WHEN"
7011 PRINT"SUDDENLY A VOICE COMES FROM NOWHERE:"
7012 PRINT"'[212]HOU HATH COME THIS FAR, AND WHAT THOU"
7013 PRINT"DIDST WAS A MISTAKE, FOR THOU SHALT"
7014 PRINT"MEET THY DOOM AND FOREVER BE MY SLAVE.'"
7020 PRINT"[211]UDDENLY A CLOUD FORMS BEFORE YOU, AND"
7021 PRINT"THEN CLEARS TO REVEAL THE BEING OF THE"
7022 PRINT"FEARED NECROMANCER."
7030 PRINT"[200]E WAVES HIS ARMS AND BEGINS TO INTONE  HIS EVIL MAGIC WORDS."
7040 GOSUB300
7050 IFCM<>2ORUD<>1THENGOTO7300
7060 PRINT"[194]EFORE HE HAS A CHANCE TO CAST HIS EVIL"
7061 PRINT"SPELL YOU ATTACK HIM WITH THE GLOWING"
7062 PRINT"SWORD. [200]ITTING HIM IN HIS BLACK HEART,"
7063 PRINT"YOU DRAW HIS LIFEBLOOD."
7070 PRINT"[200]E LETS OUT A DEAFENING SCREAM, FALLS"
7071 PRINT"TO HIS KNEES, AND CLUTCHES HIS CRITICAL"
7072 PRINT"WOUND. [200]E THEN TURNS TO YOU AND SPEAKS:"
7073 PRINT"'[212]HOU HATH WON NOTHING. [201] SHALT RETURN.'"
7080 PRINT"[200]E THEN FALLS TO THE GROUND AND HIS BODYEXPLODES INTO NOTHINGNESS."
7090 PRINT:PRINT"[217]OU HAVE DEFEATED HIM. [217]OU HAVE KILLED"
7091 PRINT"THE DREADED NECROMANCER. [217]OU ALONE HAVE"
7092 PRINT"LIFTED THE CURSE OF THE NECROMANCER."
7093 PRINT"[212]HE PLAGUE OF THE GENERATIONS IS GONE."
7100 PRINT"[212]HE SPELL HAS BEEN BROKEN. [212]HE DARK"
7101 PRINT"LANDS ARE BRIGHT. [212]HE WRAITH OF THE"
7102 PRINT"NECROMANCER SOARS AWAY... IN THE NIGHT."
7200 GOTO63000
7300 PRINT"[212]HE NECROMANCER SPEAKS: '[212]HOU ART"
7301 PRINT"STUPID, AND NOW THOU ART MY SLAVE.'"
7310 PRINT"[200]E THEN CASTS HIS EVIL SPELL UPON YOU."
7311 PRINT"[211]UDDENLY YOU FEEL PAIN LIKE YOU HAVE"
7312 PRINT"NEVER IMAGINED. [212]HE LAST THING YOU SEE"
7313 PRINT"IS THE EVIL GRIN OF THE NECROMANCER AS"
7314 PRINT"HE WATCHES YOU DIEIN AGONY.":GOTO50000
7499 :
7500 REM *** LOCATION #15 ***
7501 :
7510 PRINT"[217]OU HAVE COME TO A NORTH-SOUTH-WEST     INTERSECTION."
7520 GOSUB300
7530 IFCM=2THENPRINT"[206]O EFFECT."
7540 IFCM=3THENLC=12:GOTO250
7550 IFCM=4THENLC=9:GOTO250
7560 IFCM=5THENPRINT"[217]OU CANNOT GO THAT DIRECTION."
7570 IFCM=6THENLC=10:GOTO250
7580 IFCM=7THENGOTO7500
7590 IFCM=9THENPRINT"[206]OTHING HERE."
7600 GOTO7520
7999 :
8000 REM *** LOCATION #16 ***
8001 :
8010 PRINT"[217]OU ARE AT A FOUR-WAY INTERSECTION."
8020 IFGL=0THENPRINT"[212]HERE IS A BAG OF GOLD ON THE GROUND."
8030 GOSUB300
8040 IFCM=2THENPRINT"[206]O EFFECT."
8050 IFCM=3THENLC=10:GOTO250
8060 IFCM=4THENLC=17:GOTO250
8070 IFCM=5THENLC=9:GOTO250
8080 IFCM=6THENLC=8:GOTO250
8090 IFCM=7THENGOTO8000
8100 IFCM=9ANDGL>0THENPRINT"[206]OTHING HERE."
8110 IFCM=9ANDCO=0THENPRINT"[199]OLD TAKEN.":GL=1
8120 GOTO8030
8499 :
8500 REM *** LOCATION #17 ***
8501 :
8510 PRINT"[217]OU ARE AT AN EAST-SOUTH-WEST           INTERSECTION."
8520 GOSUB300
8530 IFCM=2THENPRINT"[206]O EFFECT."
8540 IFCM=3THENLC=16:GOTO250
8550 IFCM=4THENPRINT"[217]OU CANNOT GO THAT DIRECTION."
8560 IFCM=5THENLC=7:GOTO250
8570 IFCM=6THENLC=5:GOTO250
8580 IFCM=7THENGOTO8500
8590 IFCM=9THENPRINT"[206]OTHING HERE."
8600 GOTO8520
8999 :
9000 REM *** LOCATION #18 ***
9001 :
9003 IFPW=1ANDCM=3THENLC=13:GOTO250
9006 IFCM=4THENLC=10:GOTO250
9007 PRINT"[217]OU ARE IN A NORTH-SOUTH PASSAGEWAY.":PRINT
9010 PRINT"[201]N THE MIDDLE OF THE PASSAGEWAY THERE"
9011 PRINT"IS A BRICK WALL PREVENTING YOU FROM"
9012 PRINT"GOING ANY FURTHER. [215]RITTEN IN GLOWING"
9013 PRINT"LETTERS ON THE GATE IS A MESSAGE:"
9015 PRINT
9020 PRINT"'[202]EWEL ON BLACK VELVET":PRINT" [208]EARL ON THE SEA"
9021 PRINT" [193]LTAR OF THE [204]UPINE [204]ORDS":PRINT" [193] RIDDLE FOR THEE"
9022 PRINT" [193]NSWER CORRECTLY TO PASS THE GATE":PRINT" [193]ND BE MY SLAVE FOR ETERNITY'"
9030 PRINT:PRINT"[212]YPE 'ANSWER' TO ANSWER THE RIDDLE."
9040 GOSUB300
9050 IFCM=2THENPRINT"[206]O EFFECT."
9060 IFCM=3ANDPW=0THENPRINT"[212]HE BIRCK WALL IS BLOCKING YOUR WAY."
9070 IFCM=3ANDPW=1THENLC=13:GOTO250
9080 IFCM=4THENLC=10:GOTO250
9090 IFCM=5ORCM=6THENPRINT"[217]OU CANNOT GO THAT DIRECTION."
9100 IFCM=7ANDPW=1THENPRINT"[217]OU ARE IN A NORTH-SOUTH HALLWAY."
9110 IFCM=7ANDPW=0THENGOTO9010
9120 IFCM=9THENPRINT"[206]OTHING HERE."
9130 IFPW=0ANDCM=8THENINPUT"[193]NSWER: ";AN$
9135 IFPW=0ANDCM=8AND(AN$="THE MOOM"ORAN$="MOON")THENPRINT"[210]IGHT. [212]HE WALL VANISHES."
9136 IFPW=0ANDCM=8AND(AN$="THE MOOM"ORAN$="MOON")THENPW=1
9140 IFPW=0ANDCM=8AND(AN$<>"THE MOON"ORAN$<>"MOON")THENPRINT"[215]RONG."
9150 GOTO9040
10500 T=0
10510 IFUD=1ANDMS=0THENT=1
10520 IFUD=2ANDHO=0THENT=1
10530 IFUD=3ANDRI<>1THENT=1
10540 IFUD=4ANDPS<>1THENT=1
10550 IFUD=5ANDSC=0THENT=1
10560 IFUD=6ANDDS=0THENT=1
10570 IFUD=7ANDCP=0THENT=1
10580 IFUD=8ANDMD<>1THENT=1
10590 IFUD=9ANDHW<>1THENT=1
10600 IFUD=10ANDGL<>1THENT=1
10610 IFT=1THENPRINT"[217]OU DO NOT HAVE THAT ITEM.":GOTO300
10620 GOTO410
11000 IFLC=1THENGOTO500
11010 IFLC=2THENGOTO1000
11020 IFLC=3THENGOTO1500
11030 IFLC=4THENGOTO2000
11040 IFLC=5THENGOTO2500
11050 IFLC=7THENGOTO3000
11060 IFLC=8THENGOTO3500
11070 IFLC=9THENGOTO4000
11080 IFLC=10THENGOTO4500
11090 IFLC=11THENGOTO5000
11100 IFLC=12THENGOTO6000
11110 IFLC=13THENGOTO6500
11120 IFLC=14THENGOTO7000
11130 IFLC=15THENGOTO7500
11140 IFLC=16THENGOTO8000
11150 IFLC=17THENGOTO8500
11160 IFLC=18THENGOTO9000
19999 :
20000 REM *** INVENTORY ***
20001 :
20010 PRINT"[201]NVENTORY:"
20020 IFMS=1THENPRINT"[205]AGIC SWORD"
20030 IFHO=1THENPRINT"[200]ORN"
20040 IFRI=1THENPRINT"[210]ED POTION"
20050 IFPS=1THENPRINT"[205]AGIC POTION"
20060 IFSC=1THENPRINT"[211]CEPTRE"
20070 IFDS=1THENPRINT"[196]RAGONSLAYER"
20080 IFCP=1THENPRINT"[195]OMPASS"
20090 IFMD=1THENPRINT"[205]AGIC DUST"
20100 IFHW=1THENPRINT"[200]OLY WATER"
20110 IFGL=1THENPRINT"[199]OLD"
20120 GOTO300
29999 :
30000 REM *** COMMANDS ***
30001 :
30010 PRINT"[195]OMMANDS:"
30020 PRINT:PRINT"[211]OUTH ([211])","[197]AST ([197])"
30030 PRINT"[206]ORTH ([206])","[215]EST ([215])"
30040 PRINT"[213]SE      ","[199]ET"
30050 PRINT"[204]OOK     ","[201]NVENTORY ([201])"
30055 PRINT"[209]UIT"
30060 GOTO300
50000 PRINT:PRINT"[217]OU ARE DEAD."
50010 INPUT"[193]NOTHER GO? ";R$
50020 IFLEFT$(R$,1)<>"Y"ANDLEFT$(R$,1)<>"[217]"THEN63000
(null)>nLENCLR
50050 GOTO200
50055 REM ?????
60000 PRINT:PRINT"[217]OU SURE YOU WANT TO QUIT?[160](Y/N)":INPUTR$
60010 IFLEFT$(R$,1)<>"Y"ANDLEFT$(R$,1)<>"[217]"THENRETURN
60020 GOTO50010
61000 T$="                         ":C=0:C$="":PRINT"[147]":POKE53281,0
61030 PRINTSPC(7)""T$:PRINTSPC(7)" [204]AIR OF THE [206]ECROMANCER [146]"
61051 PRINTSPC(7)""T$:PRINT:PRINTTAB(18)"BY"
61060 PRINT:PRINTSPC(15)"[210]OB [210]UDD"
61070 PRINT:PRINTSPC(12)"[195]OPYRIGHT 1985"
61080 PRINT:PRINT:PRINT:PRINT"     [204][207][193][196][211][212][193][210] IS NOT PUBLIC DOMAIN."
61090 PRINT:PRINT"  [208]LEASE RESPECT THE AUTHOR'S RIGHTS."
61100 PRINT:PRINT"      [208]RESS SPACE BAR TO CONTINUE."
61110 FORCC=1TO48:GETK$:IFK$=" "THEN61130
61120 IFCC=1THENPRINTMID$(C$,C+2,1)"[145][145]";:C=NOT(C)
61125 NEXT:GOTO61100
61130 PRINTC$:RETURN
63000 REM    CONNECT BACK TO L.S.
63002 PRINT"[147]LOAD"CHR$(34)"PAYLOAD"CHR$(34)",8":PRINT"RUN"
63004 POKE198,0:POKE631,13:POKE632,13:POKE198,2:END